Evan Reichard
b93249daf7
- Add new `qwen3-8b-vision` model with multimodal support using mmproj file - Add new `qwen2.5-coder-7b-instruct` model with FIM enabled via `--fim-qwen-7b-default` - Update CUDA device usage from `CUDA0` to `CUDA1` for `olmoe-7b-instruct` and `phi-mini-8b-instruct` - Upgrade llama.cpp to version 7426 with updated hash and CUDA architectures (61;86) - Add Copilot acceptance shortcut `<C-J>` in insert mode and disable tab mapping - Improve cache type settings across multiple models for better performance
43 lines
1.1 KiB
Nix
43 lines
1.1 KiB
Nix
{ pkgs }:
|
|
(pkgs.llama-cpp.override {
|
|
cudaSupport = true;
|
|
blasSupport = true;
|
|
rocmSupport = false;
|
|
metalSupport = false;
|
|
vulkanSupport = true;
|
|
}).overrideAttrs
|
|
(oldAttrs: rec {
|
|
version = "7426";
|
|
src = pkgs.fetchFromGitHub {
|
|
owner = "ggml-org";
|
|
repo = "llama.cpp";
|
|
tag = "b${version}";
|
|
hash = "sha256-la+hA+Fw3xFjAyR4XgNmehghGS6zAKh9gHqJnlw2tMQ=";
|
|
leaveDotGit = true;
|
|
postFetch = ''
|
|
git -C "$out" rev-parse --short HEAD > $out/COMMIT
|
|
find "$out" -name .git -print0 | xargs -0 rm -rf
|
|
'';
|
|
};
|
|
|
|
# Auto CPU Optimizations
|
|
cmakeFlags = (oldAttrs.cmakeFlags or [ ]) ++ [
|
|
"-DGGML_NATIVE=ON"
|
|
"-DGGML_CUDA_ENABLE_UNIFIED_MEMORY=1"
|
|
"-DCMAKE_CUDA_ARCHITECTURES=61;86" # GTX 1070 / GTX 1080ti / RTX 3090
|
|
];
|
|
|
|
# Disable Nix's march=native Stripping
|
|
preConfigure = ''
|
|
export NIX_ENFORCE_NO_NATIVE=0
|
|
${oldAttrs.preConfigure or ""}
|
|
'';
|
|
|
|
# Apply Patches
|
|
patchFlags = [ "-p1" ];
|
|
patches = (oldAttrs.patches or [ ]) ++ [
|
|
./oneof-not-unrecognized-schema.patch
|
|
./additionalprops-unrecognized-schema.patch
|
|
];
|
|
})
|